SET SKIP Command

Visual FoxPro 9.0 SP2

SET SKIP Command


SET SKIP TO [TableAlias1 [, TableAlias2] ...]

Parameters

TO TableAlias1[, TableAlias2] ...

Specifies the aliases of multiple child tables. These are used to create a one-to-many relationship with a parent table. Use commas to separate the aliases. In commands that support a scope (DISPLAY, LIST, and so on), records in the parent table are repeated for each corresponding record in the child table.

Use SET SKIP TO without additional arguments to remove the one-to-many relationship from the parent table open in the currently selected work area. Any one-to-one relationships remain in effect. One-to-one relationships can be removed with SET RELATION TO.

Remarks

Using SET RELATION, you can establish relations between tables open in different work areas. When the record pointer is moved in the parent table, the record pointer in the child table moves to the first corresponding record. The relational expression in SET RELATION determines where the record pointer moves in the child table. A one-to-one relation is created — for each record in the parent table, the record pointer moves to the first matching record in the child table. If a matching record can't be found in the child table, the record pointer in the child table moves to the end of the table.

Frequently, a child table contains multiple records that correspond to one record in the parent table. SET SKIP lets you establish a one-to-many relationship between one record in the parent table and multiple records in the child table. When you skip through the parent table, the record pointer remains on the same parent record until the record pointer moves through all related records in the child table.

To establish a one-to-many relationship, first create the relationship between the parent and child table with SET RELATION. Then, issue SET SKIP to create a one-to-many relationship.

Example

This example below finds all occurrences in three tables where each item in the first field are the same. It does this by using scanning the first table, which has a relation into a second, which table has a relation into a third. The first table then does a SET SKIP for the other two tables. A SET SKIP on the second table has no effect. It affects only the table being scanned (replaced, etc.). In the example, eight matches are found.

	Copy Code
CLOSE DATABASES * Creates parent table with values a and b in Name field CREATE TABLE Parent FREE (Name C(1), Val C(10)) INSERT INTO Parent VALUES ('a', 'Parent.a1') INSERT INTO Parent VALUES ('b', 'Parent.b1') SELECT 0 && Child1 will have two a's and two b's CREATE TABLE Child1 FREE (Name1 C(1), Val C(10)) INSERT INTO Child1 VALUES ('a', 'Child1.a1') INSERT INTO Child1 VALUES ('b', 'Child1.b1') INSERT INTO Child1 VALUES ('b', 'Child1.b2') INSERT INTO Child1 VALUES ('a', 'Child1.a2') INDEX ON Name1 TAG tagName && The tag name is irrelevant SELECT 0 && Child2 will have two a's and two b's CREATE TABLE Child2 FREE (Name2 C(1), Val C(10)) INSERT INTO Child2 VALUES ('b', 'Child1.b1') INSERT INTO Child2 VALUES ('b', 'Child1.b2') INSERT INTO Child2 VALUES ('a', 'Child1.a1') INSERT INTO Child2 VALUES ('a', 'Child1.a2') INDEX ON Name2 TAG tagName && The tag name is irrelevant SELECT Child1 SET RELATION TO Name1 INTO Child2 SELECT Parent SET RELATION TO Name INTO Child1 SET SKIP TO Child1, Child2 && Parent gets both skips. && Otherwise, only four record triplets && would be listed. SCAN ALL && There will be eight triplets: four a's and four b's ? Parent.Val, Child1.Val, Child2.Val ENDSCAN

Copy Code

CLOSE DATABASES
* Creates parent table with values a and b in Name field
CREATE TABLE Parent FREE (Name C(1), Val C(10))
INSERT INTO Parent VALUES ('a', 'Parent.a1')
INSERT INTO Parent VALUES ('b', 'Parent.b1')
SELECT 0     && Child1 will have two a's and two b's
CREATE TABLE Child1 FREE (Name1 C(1), Val C(10))
INSERT INTO Child1 VALUES ('a', 'Child1.a1')
INSERT INTO Child1 VALUES ('b', 'Child1.b1')
INSERT INTO Child1 VALUES ('b', 'Child1.b2')
INSERT INTO Child1 VALUES ('a', 'Child1.a2')
INDEX ON Name1 TAG tagName   && The tag name is irrelevant
SELECT 0  && Child2 will have two a's and two b's
CREATE TABLE Child2 FREE (Name2 C(1), Val C(10))
INSERT INTO Child2 VALUES ('b', 'Child1.b1')
INSERT INTO Child2 VALUES ('b', 'Child1.b2')
INSERT INTO Child2 VALUES ('a', 'Child1.a1')
INSERT INTO Child2 VALUES ('a', 'Child1.a2')
INDEX ON Name2 TAG tagName     && The tag name is irrelevant
SELECT Child1
SET RELATION TO Name1 INTO Child2
SELECT Parent
SET RELATION TO Name INTO Child1
SET SKIP TO Child1, Child2 && Parent gets both skips.
           && Otherwise, only four record triplets 
           && would be listed.
SCAN ALL  && There will be eight triplets: four a's and four b's
   ? Parent.Val, Child1.Val, Child2.Val
ENDSCAN

SET SKIP Command

Parameters

Remarks

Example

See Also

Reference

Other Resources